Terraform (AWS)

開始する前に、Access Key を生成する必要があります。以降の例では、生成した Access Key ID と Secret Access Key の値を表す access_key_id と access_key_secret 変数を使います。

この例では、AWS プロバイダー ↗ を使い、Terraform で R2 を設定します。

terraform ↗ をインストールした状態で、次を行います。

main.tf を作成するか、既存の Terraform 設定を編集します。
endpoints.s3 のエンドポイント URL に Cloudflare アカウント ID を入れます。
access_key と secret_key に、対応する R2 API 認証情報を入れます。
プロバイダー設定で skip_region_validation = true、skip_requesting_account_id = true、skip_credentials_validation = true が設定されていることを確認します。

terraform {
  required_providers {
    aws = {
      source = "hashicorp/aws"
      version = "~> 5"
    }
  }
}

provider "aws" {
  region = "us-east-1"

  access_key = <R2 Access Key>
  secret_key = <R2 Secret Key>

	# Required for R2.
	# These options disable S3-specific validation on the client (Terraform) side.
  skip_credentials_validation = true
  skip_region_validation      = true
  skip_requesting_account_id  = true

  endpoints {
    s3 = "https://<account id>.r2.cloudflarestorage.com"
  }
}

resource "aws_s3_bucket" "default" {
  bucket = "<org>-test"
}

resource "aws_s3_bucket_cors_configuration" "default" {
  bucket   = aws_s3_bucket.default.id

  cors_rule {
    allowed_methods = ["GET"]
    allowed_origins = ["*"]
  }
}

resource "aws_s3_bucket_lifecycle_configuration" "default" {
  bucket = aws_s3_bucket.default.id

  rule {
    id     = "expire-bucket"
    status = "Enabled"
    expiration {
      days = 1
    }
  }

  rule {
    id     = "abort-multipart-upload"
    status = "Enabled"
    abort_incomplete_multipart_upload {
      days_after_initiation = 1
    }
  }
}

その後、terraform plan で変更内容を確認し、terraform apply で変更を適用できます。